`ifndef _BVM_MACROS201112_SVH_
`define _BVM_MACROS201112_SVH_

`define bvm_driver_declaration(_if_, _tran_) typedef bvm_simple_driver #(virtual _if_, _tran_) _if_``_driver;
`define bvm_responder_declaration(_if_, _tran_) typedef bvm_simple_responder #(virtual _if_, _tran_) _if_``_responder;
`define bvm_monitor_declaration(_if_, _tran_) typedef bvm_simple_monitor #(virtual _if_, _tran_) _if_``_monitor;

`define bvm_interface_utils(_if_, _tran_) \
   `bvm_driver_declaration(_if_, _tran_) \
   `bvm_responder_declaration(_if_, _tran_) \
   `bvm_monitor_declaration(_if_, _tran_)

/**
 * @brief Basic Driver.
 *
 * Receives transactions of type @c T from an @c ovm_get_port and
 * forwards them to the method @c do_drive of a virtual interface of
 * type @c VIF, modport @c driver. The interface method @c
 * driver_initial is called at initialisation.
 *
 * @param VIF A virtual interface providing methods @c driver_initial
 * and @c do_drive via modport @c driver.
 * @param T Transaction type, input to @c do_drive.
 *
 * @param in The ovm_get_port.
 * @param vif Virtual interface.
 */
class bvm_simple_driver #(type VIF = int, type T = ovm_sequence_item) extends ovm_component;
   typedef bvm_simple_driver #(VIF, T) this_t;
   `ovm_component_param_utils(this_t)

   ovm_get_port #(T) in;
   VIF vif;
   T sample;

   function new(string name, ovm_component parent);
      super.new(name, parent);
      in = new("in", this);
   endfunction

   task run();
      recording_detail = OVM_FULL;

      vif.driver.driver_initial();

      forever begin
         in.get(sample);

         begin_tr(sample, {m_name, "_tran"}, "Driven stimulus");
         vif.driver.do_drive(sample);
         end_tr(sample);
      end
   endtask
endclass


/**
 * @brief Basic Responder.
 *
 * Interacts with a virtual interface of type @c VIF, modport @c
 * responder, via its method @c do_respond and forwards the completed
 * transactions of type @c T to an @c ovm_put_port. The interface
 * method @c responder_initial is called at initialisation.
 *
 * @param VIF A virtual interface providing methods @c
 * responder_initial and @c do_respond via modport @c responder.
 * @param T Transaction type, output from @c do_respond.
 *
 * @param vif Virtual interface.
 * @param out The ovm_put_port.
 */
class bvm_simple_responder #(type VIF = int, type T = ovm_sequence_item) extends ovm_component;
   typedef bvm_simple_responder #(VIF, T) this_t;
   `ovm_component_param_utils(this_t)

   ovm_put_port #(T) out;
   VIF vif;
   T sample;

   function new(string name, ovm_component parent);
      super.new(name, parent);
      out = new("out", this);
   endfunction

   task run();
      recording_detail = OVM_FULL;

      vif.responder.responder_initial();
      forever begin
         sample = new;
         begin_tr(sample, {m_name, "_tran"}, "Received output");
         vif.responder.do_respond(sample);
         out.put(sample);
         end_tr(sample);
      end
   endtask
endclass


/**
 * @brief Basic Monitor.
 *
 * Monitors a virtual interface of type @c VIF, modport @c monitor,
 * via its method @c do_monitor, and forwards the generated
 * transactions of type @c T to an @c ovm_put_port. The interface
 * method monitor_initial is called at initialisation.
 *
 * @param VIF A virtual interface providing methods @c monitor_initial
 * and @c do_monitor via modport @c monitor.
 * @param T Transaction type, output from @c do_monitor.
 *
 * @param vif Virtual interface.
 * @param out The ovm_put_port.
 */
class bvm_simple_monitor #(type VIF = int, type T = ovm_sequence_item) extends ovm_component;
   typedef bvm_simple_monitor #(VIF, T) this_t;
   `ovm_component_param_utils(this_t)

   ovm_put_port #(T) out;
   VIF vif;
   T sample;

   function new(string name, ovm_component parent);
      super.new(name, parent);
      out = new("out", this);
   endfunction

   task run();
      recording_detail = OVM_FULL;

      vif.monitor.monitor_initial();

      forever begin
         sample = new;
         begin_tr(sample, {m_name, "_tran"}, "Observed output");
         vif.monitor.do_monitor(sample);
         out.put(sample);
         end_tr(sample);
      end
   endtask
endclass

`endif // _BVM_MACROS201112_SVH_